Effect[] efs = new Effect[10];
int efCnt = 0;

void setup() {
  size( 800,380 );
  for(int i=0; i<efs.length; i++ ){
    efs[i] = new Effect();
  }
}

void draw() {
  background( 0 );
  //
  for(int i=0; i<efs.length; i++ ){
    efs[i].display();
  }
}

void mousePressed() {
  // mouseX, mouseY
  println( "mouse pressed" );
  
    // line();
    efs[efCnt].startObj( mouseX, mouseY );
    efCnt++;
    if( efCnt == efs.length ){ efCnt=0; }
    
}



class Effect {
  int px;
  int py;
  
  int dBright = 10;
  boolean drawFlg = false;
  int cR = 0;
  int cG = 240;
  int cB = 96;
  float angle=0;
  int objType = 0;
  
  int strokeW = 20;
  
  float rAngle;
  float dAngle = 20;
  int rSize;
  int dSize = 20;
  
  
  
  Effect() {
  }
  
  void startObj(int x,int y ) {
    this.px = x;
    this.py = y;
    this.drawFlg = true;
    this.angle = random(0, 360 );
    cR = 0;
    cG = 240;
    cB = 96;
    objType = int(random(0,4));
    rAngle = angle;
    rSize = strokeW;
    noFill();
  }
  
  void display() {
    if( drawFlg ){
      // 座標形の変更
      strokeWeight(strokeW);
      stroke( cR, cG, cB );
      cR = cR - dBright; if( cR<0 ){ cR=0; }
      cG = cG - dBright; if( cG<0 ){ cG=0; }
      cB = cB - dBright; if( cB<0 ){ cB=0; }
      if( cR==0 && cG==0 && cB==0 ){
        drawFlg = false;
      }
      pushMatrix();
      translate( px,py );
      rotate( radians( angle ) );
      
      if( objType==0 ){
        // 線
        strokeWeight(strokeW*2);
        line( 1024,0, -1024,0 );
      } else if( objType == 1 ){
        // ○
        ellipse( 0,0, rSize, rSize );
        ellipse( 0,0, rSize+50, rSize+50 );
        rSize = rSize + dSize;
      } else if( objType == 2 ){
        // □
        rectMode( CENTER );
        rotate( radians( rAngle ) );
        rect( 0, 0, rSize, rSize );
        rSize = rSize + dSize;
        rAngle = rAngle + dAngle;
      } else if( objType == 3 ){
        // △
        // dx = sin( 60 );
        float dx,dy;
        dx = rSize * cos( radians( 60 ) );
        dy = rSize * sin( radians( 60 ) );
        rotate( radians( rAngle ) );
        triangle( 0, int(dy*2/3), int(dx), int(-dy/3), int(-dx), int(-dy/3) );
        rSize = rSize + dSize;
        rAngle = rAngle + dAngle;
      }
      
      popMatrix();
    }
  }

}